TI 82 Information

The program "FINANCE" will provide the TI-82 with financial capabilities. 

Financial Variables

N, number of periods
I, rate of interest per period
PMT, payment per period
PV, present value
FV, future value

Conventions

Payments which increase the balance are positive numbers.
Payments which decrease the balance are negative numbers.
Future values are balances, usually entered as positive numbers.

Floating Decimal

Press MODE, place the cursor on Float, press ENTER, press CLEAR.

Financial Mode

Press PRGM, then choose FINANCE.

Clearing Financial Data

Choose CLEAR VALUES, then press ENTER.

Beginning Annuities

Choose ENTER VALUES, TYPE, and choose TYPE 1.  Turn off similarly.

Entering Financial Data

Choose ENTER VALUES, select the variable, enter its value and press ENTER.

Computing Values

Choose COMPUTE VALUE and select the variable.

Example:

Tom's account begins with $500, and earns 6% per year, compounded monthly. He deposits an additional $50 at the end of each month. What will the balance be at the end of one year?

The variables are:

N = 12

I = 6/12 = 0.5

PMT = 50 increasing

PV = 500

FV = ???

The keystrokes are:

PRGM, "FINANCE", ENTER, ENTER
"CLEAR VALUES", ENTER
"ENTER VALUES"
"N", 12, ENTER
"I", 0.5, ENTER
"PMT", 50, ENTER

"PV", 500, ENTER
"<<MAIN>>", "COMPUTE VALUE", FV

The answer is $1,147.62, rounded to the nearest cent.

The "FINANCE" Program for the TI-82

• Prgm1:FINANCE
• :Lbl 0:ClrHome
• :Menu("MAIN:","ENTER VALUES",9,"COMPUTE VALUE",7,"REVIEW VALUES",8,"CLEAR VALUES",X,"QUIT",Z)
• :Lbl X:0→N:0→I:0→M:0→P:0→F:0→K
• :Lbl 8:Disp "N,I,PMT,PV,FV:"
• :Disp N,I,M,P,F
• :If K=0:Disp "ORD-PRESS ENTER"
• :If K=1:Disp "DUE-PRESS ENTER"
• :If K(K-1)≠0:Disp "----PRESS ENTER"
• :Pause :Goto 0
• :Lbl 9:ClrHome
• :Menu("ENTER VALUES","N",1,"I",2,"PMT",3,"PV",4,"FV",5,"TYPE",6,"<<MAIN>>",0)
• :Lbl 1:Prompt N:Goto 9
• :Lbl 2:Disp "PCT PER PERIOD": Prompt I:Goto 9
• :Lbl 3:Disp "+=INC, -=DEC":Prompt M:Goto 9
• :Lbl 4:Prompt P:Goto 9
• :Lbl 5:Prompt F:Goto 9
• :Lbl 6:Disp "0=ORD, 1=DUE":Prompt K:Goto 9
• :Lbl 7:ClrHome:Disp "THINKING"
• :Menu("COMPUTE VALUE","N",A,"I",B,"PMT",C,"PV",D,"FV",E,"<<MAIN>>",0)
• :Lbl A:If I=0 or M+.01I(MK+P)=0 or I≤-100:Goto Y
• :If (M+.01I(MK+F))/(M+.01I(MK+P))≤0:Goto Y
• :ln ((M+.01I(MK+F))/(M+.01I(MK+P)))/ln (1+.01I)→N:Goto 8
• :Lbl B:If I=0 or I≤-100:Goto Y
• :solve((P+100M(1+.01KI)/I)(1-(1+.01I)^N)-P+F,I,10)→I:Goto 8
• :Lbl C:If N=0 or I=0 or I≤-100:Goto Y
• :.01I((F-P)/((1+.01I)^N-1)-P)/(1+.01KI)→M:Goto 8
• :Lbl D:If I=0 or I≤-100:Goto Y
• :(F+100M(1+.01KI)/I)((1+.01I)^-N-1)+F→P:Goto 8
• :Lbl E:If I=0 or I≤-100:Goto Y
• :(P+100M(1+.01KI)/I)((1+.01I)^N-1)+P→F:Goto 8
• :Lbl Y:Disp "ERROR":Disp "PRESS ENTER":Pause :Goto 0
• :Lbl Z:Stop